IA-32 汇编 GAS cdecl 调用约定

# make this routine available outside this translation unit
.globl string_to_integer

string_to_integer:
    # function prologue
    push %ebp
    mov %esp, %ebp
    push %esi

    # initialize result (%eax) to zero
    xor %eax, %eax
    # fetch pointer to the string
    mov 8(%ebp), %esi

    # clear high bits of %ecx to be used in addition
    xor %ecx, %ecx
    # do the conversion
string_to_integer_loop:
    # fetch a character
    mov (%esi), %cl
    # exit loop when hit to NUL character
    test %cl, %cl
    jz string_to_integer_loop_end
    # multiply the result by 10
    mov $10, %edx
    mul %edx
    # convert the character to number and add it
    sub $'0', %cl
    add %ecx, %eax
    # proceed to next character
    inc %esi
    jmp string_to_integer_loop
string_to_integer_loop_end:

    # function epilogue
    pop %esi
    leave
    ret

这个 GAS 风格的代码将十进制字符串转换为第一个参数，在调用此函数之前将其转换为堆栈，并将其转换为整数并通过%eax 返回。%esi 的值被保存，因为它是 callee-save 寄存器并被使用。

不检查溢出/包装和无效字符以使代码简单。

在 C 中，这段代码可以像这样使用（假设 unsigned int 和指针长度为 4 字节）：

#include <stdio.h>

unsigned int string_to_integer(const char* str);

int main(void) {
    const char* testcases[] = {
        "0",
        "1",
        "10",
        "12345",
        "1234567890",
        NULL
    };
    const char** data;
    for (data = testcases; *data != NULL; data++) {
        printf("string_to_integer(%s) = %u\n", *data, string_to_integer(*data));
    }
    return 0;
}

注意：在某些环境中，汇编代码中的两个 string_to_integer 必须更改为 _string_to_integer（添加下划线）才能使其与 C 代码一起使用。